feat: move configuration files inside home folder

home/.config/zsh/ohmyzsh/plugins/gcloud/README.md

@@ -0,0 +1,24 @@
+# gcloud
+
+This plugin provides completion support for the
+[Google Cloud SDK CLI](https://cloud.google.com/sdk/gcloud/).
+
+To use it, add `gcloud` to the plugins array in your zshrc file.
+
+```zsh
+plugins=(... gcloud)
+```
+
+It relies on you having installed the SDK using one of the supported options
+listed [here](https://cloud.google.com/sdk/install).
+
+## Plugin Options
+
+* Set `CLOUDSDK_HOME` in your `zshrc` file before you load oh-my-zsh if you have
+your GCloud SDK installed in a non-standard location. The plugin will use this
+as the base for your SDK if it finds it set already.
+
+* If you do not have a `python2` in your `PATH` you'll also need to set the
+`CLOUDSDK_PYTHON` environment variable at the end of your `.zshrc`. This is
+used by the SDK to call a compatible interpreter when you run one of the
+SDK commands.

home/.config/zsh/ohmyzsh/plugins/gcloud/gcloud.plugin.zsh

@@ -0,0 +1,52 @@
+#####################################################
+# gcloud plugin for oh-my-zsh                       #
+# Author: Ian Chesal (github.com/ianchesal)         #
+#####################################################
+
+if [[ -z "${CLOUDSDK_HOME}" ]]; then
+  search_locations=(
+    "$HOME/google-cloud-sdk"
+    "/usr/local/share/google-cloud-sdk"
+    "/usr/local/Caskroom/google-cloud-sdk/latest/google-cloud-sdk"
+    "/opt/homebrew/Caskroom/google-cloud-sdk/latest/google-cloud-sdk"
+    "/opt/homebrew/share/google-cloud-sdk"
+    "/usr/share/google-cloud-sdk"
+    "/snap/google-cloud-sdk/current"
+    "/snap/google-cloud-cli/current"
+    "/usr/lib/google-cloud-sdk"
+    "/usr/lib64/google-cloud-sdk"
+    "/opt/google-cloud-sdk"
+    "/opt/google-cloud-cli"
+    "/opt/local/libexec/google-cloud-sdk"
+    "$HOME/.asdf/installs/gcloud/*/"
+  )
+
+  for gcloud_sdk_location in $search_locations; do
+    if [[ -d "${gcloud_sdk_location}" ]]; then
+      CLOUDSDK_HOME="${gcloud_sdk_location}"
+      break
+    fi
+  done
+  unset search_locations gcloud_sdk_location
+fi
+
+if (( ${+CLOUDSDK_HOME} )); then
+  # Source path file
+  if [[ -f "${CLOUDSDK_HOME}/path.zsh.inc" ]]; then
+    source "${CLOUDSDK_HOME}/path.zsh.inc"
+  fi
+
+  # Look for completion file in different paths
+  for comp_file (
+    "${CLOUDSDK_HOME}/completion.zsh.inc"             # default location
+    "/usr/share/google-cloud-sdk/completion.zsh.inc"  # apt-based location
+  ); do
+    if [[ -f "${comp_file}" ]]; then
+      source "${comp_file}"
+      break
+    fi
+  done
+  unset comp_file
+
+  export CLOUDSDK_HOME
+fi